参照の変数名は_ref付きに。
テーブルから正規表現を生成してDRYに。
if-elsif-elsif-elseの連鎖は止めてテーブル参照に。
エラー発生でundefを返さずに例外を出す。
ソースをコピペしないでサブルーチンやモジュールにまとめる。

K&Rスタイルで書く。

my @names = (
    'hoge',
    'fuga',
);

BSDスタイルとGNUスタイルは使わない。

キーワードと開きカッコのあいだにスペースを入れる。サブルーチンと混同しないように。

for my $result (@results) {
    print_sep();
}

サブルーチンや変数名と後続の開きカッコのあいだにスペースを入れない。

組み込み関数や特定の標準モジュールサブルーチンは不要なカッコを使わない。carp, croak, first, max, prompt。

while (my $record = <$results_file>) {
    chomp $record;
    my ($name, $votes) = split "\t", $record;
    print 'Vote for ',
    #略
}

サブルーチンとしてカッコを付ける時はあいだにスペースを入れない。

while (my $record = <$results_file>) {
    chomp( $record );
    my ($name, $votes) = split("\t", $record);
    print(
        'Vote for ',
    #略
    );
}

ハッシュのキーや配列のインデックスと周囲のカッコのあいだにスペースを入れる。

$candidates[$i] = $incumbent{ $candidates[$i]{ get_region() } };

2項演算子の前後にスペースを入れる。優先度の低い演算子の左右に2こ以上のスペースを入れて見やすくする。
単項演算子（「!」や「-」）と変数のあいだはスペースを入れない。
名前付き単項演算子（sin. cos, exp）は関数のようにスペースを入れる。

ブロックに文が一つしかなくてもセミコロンを付ける。
文が一つだけのmapプロック、grepブロックの場合はセミコロンを省略する。

複数行リストの値のあとにコンマを入れる。最後の行（値）のあとにもコンマを入れる。

一行の文字数は78列まで。

スペース4つのインデントを使う。

タブは使わない。vimは:set expandtabで。
文字としてタブを使う場合は\tで。

1行に1つの文。mapとgrepも。

処理ごとに分割して前後に空行を入れて段落にする。段落の先頭に1行コメントを入れる。

}とelseは別の行に。

    if ($hoge) {
        $fuga++;
    }
    else {
        $hige++;
    }

関連する値は縦に整列させる。

長い式は演算子の前で分割する。

文の途中に長い式が有る場合は、変数に代入して独立させる。

長い式は最も優先度の低い演算子でわける。

長い代入式は=の前でわける。

$predicted_val
    = ($minimum + $maximum) / 2
      + $predicted_change * max($fudge_factor, $local_epsilon);

長い式の3項演算子は?と:を縦に揃える。

長いリストはカッコで囲む。

my @months = qw(
    January  February  March
    April    May       June
    July     August    September
    October  November  December
);

perltidyを使う。（今のバージョンのperltidyなら、~/.perltidyrcに-pbpを書くか-pbpを指定すれば良い）

命名規則。
パッケージは<名詞>::<形容詞>::<形容詞>
変数は$<形容詞>_<名詞>もしくは$<名詞>
参照テーブルとして使うハッシュや配列は%<名詞>_<前置詞>。前置詞はofやforなど。
サブルーチンは<動詞>_<名詞>か<動詞>_<形容詞>_<名詞>など。（<動詞>[_<形容詞>]?_<名詞>[_<前置詞>|<分詞>]?）

is_validやhas_foundなど真偽値にちなんだ名前にする。

リファレンス変数の名前には_refを付ける。

配列は複数形、ハッシュは単数形の名前を付ける。
例外として、参照テーブルとして一つの値を取り出すために使う配列は単数形。

単語の区切りはアンダースコアで。キャメルケースは使わない。

サブルーチン、メソッド、変数、ラベル付き引数の名前は小文字のみ。
パッケージ、クラスには大文字と小文字を。
定数には大文字のみを。
例外として固有名詞や略語や単位はなじみのある表記に従う。（HTTP、W3C::XHTML、LaTeX、Mbps）

省略する時はorigやlenやdescなど先頭を使う。orgnやlnghやdscnなど母音省略はしない。

省略するのは意味が分かるときだけにする。

last、set、left、right、no、secondなど、意味が複数ある単語を名前に使わない。

モジュールやクラスの内部専用のサブルーチン名には、先頭に_を付ける。

変数展開してほしい時だけダブルクォーテーションの"で囲む。（もしくはqq{ ... }）
変数展開が無い場合はシングルクォーテーションの'で囲む。
文字列にシングルクォーテーションが含まれる時はq{ ... }で囲む。（\'は使わない）
文字列にシングルクォーテーションとかっこが含まれる時はq[ ... ]角カッコで囲む。
複数行に文字列がある場合はq{ ... }などの汎用的な囲みで統一する。

空の文字列は''ではなくq{}を使う。

スペース一つは' 'ではなくq{ }を使う。
タブは"\t"を使う。
'"'や"\""は使わずに、q{"}やq{'}を使う。
join(',', @list)は使わずにjoin(q{,}, @list)を使う。

数値エスケープではなく名前付き文字エスケープを使う。

$escape_seq = "\177\006\030Z"; #これではなく

use charnames qw( :full );
$escape_seq = "\N{DELETE}\N{ACKNOWLEDGE}\N{CANCEL}Z"; #これを使う

名前付き定数を使う。use constantは使わない。
use Readonlyを使う。

10進数の先頭に0を付けない。（8進数になってしまう）
8進数を使う時はoctを使用する。

桁の多い数字はアンダースコアで任意に区切れる。

文字列に\nが含まれていてソースコードが一行に収まらないときは、改行の後で区切る。

$usage = "Usage: $0 <file> [-full]\n"
         . "(Use -full option for full dump)\n"
         ;

文字列が2行を超える時はヒアドキュメントを使う。

ヒアドキュメントはインデントが崩れるので、サブルーチン（ゼアドキュメント）か定義済み変数にする。

END_で始まる大文字のターミネータを使う。

変数展開しない場合はシングルクォーテーションの'でターミネータを囲む。
変数展開する場合はダブルクォーテーションの"で囲む。クォーテーションの省略はしない。

ベアワードは使わない。use strict;を使う。

ファットコンマの=>はペアの時に使う。

%default_service_record = {
    name => '<unkown>',
    rank => 'Recruit',
}

サブルーチンに名前付き引き数を渡すときに使う。

$text = format_text ({ src=>$raw_text, margins=>[1,62] });

定数を作成するときに使う。

Readonly my $ESCAPE_SEQ => "\N{DELETE}\N{ACKNOWLEDGE}\N{CANCEL}Z";

スカラーコンマは使わない。doとセミコロンを使う。コンマはリスト項目を分割する事にだけ使う。

優先度の高い!演算子と、優先度の低い論理否定notを混在させない。
andとnotはいっさい使わない。
orはcroakなど例外を送出するときに使う。

リストは全てカッコで囲む。
カッコ( )のかわりに間違えて角カッコの[ ]を使うと匿名配列になってしまうので注意。

文字列リストの有無はハッシュテーブルで。
その他リストの有無はList::MoreUtilsのany()で。

どうしても必要なとき以外はmyによるレキシカル変数だけを使う。

パッケージ変数は使用しない。
（アクセサを使ってレキシカル変数を使う）

パッケージ変数をやむを得ず変更する時はlocalを使う。

use English;

正規表現のマッチ変数（$` $& $' $PREMATCH $MATCH $POSTMATCH）はスコープがグローバルでどこで書き変わったのか混乱するので絶対に使用してはならない。
Regexp::MatchContextモジュールを使う。

$_の乱用は混乱の元。

for ( @_ ? @_ : $_ ) {
    s{hoge}{}xms; # これは良くない
}

ではなくて

for my $orig_args ( @_ ? @_ : $_ ) {
    $orig_args =~ s{hoge}{}xms;# こうする
}

配列を最後から数える時はマイナスのインデックスを使う。

配列スライスやハッシュスライスを利用する。

@frames[-1,-2,-3];
@active{'top', 'prev', 'backup'};

は

($frames[-1], $frames[-2], $frames[-3]);
($active{'top'}, $active{'prev'}, $active{'backup'});

と同じ。
@hoge[1..10]は1から10。
@hoge[-1..-9]はダメ（空リストになる）。@hoge[-9..-1]はok。

スライスからスライスへの代入の時は項目ごとに縦に揃える。

スライスのキーやインデックスが多い時はハッシュにまとめる。

基本として、後置きのifではなくプロック形式の前置きifを使う。

例外としてnext, last, redo, return, goto, die, croak, throwの時は後置きifを使う。

後置きのunless, for, while, untilを使わない。

unless, untilは使わない。
特にnotや!が含まれた二重否定や、不等号を含んだunlessは絶対に使わない。
ifを使う。

for (my $i=1; $i<=$MAX; $i++)という3部構成のCスタイルのforは使わない。

ループで配列やハッシュのインデックスを使わない。
配列を直接ループさせる。

for my $client (@clients) {
    $client->hoge(); # ok
}

インデックスのループは重いからダメ。

for my $n (0..$#clients) {
    $clients[$n]->hoge(); # 重い
}

ハッシュはvaluesをループさせる。（valuesはコピーのリストではなくエイリアスのリストが返る）

for my $trans_word (values %trans_for) {
    if ( $trans_word =~ m/hoge/xms) {
        $trans_word = 'FUGA'; # ok
    }
}

キーでループすると重いからダメ。

for my $orig_word (keys %trans_for) {
    if ( $trans_for{$orig_word} =~ m/hoge/xms) {
        $trans_for{$orig_word} = 'FUGA'; # 重い
    }
}

ループ内では添字を1回以上指定しない。
必要な時はData::Aliasを使う。

for, whileは$_ではなくmy $hogeで名前付きレキシカル変数を使う。

forの変数は必ずmyを使う。

リストから新しいリストを生成するときはforじゃなくmapを使う。

my @sqrt_results = map { sqrt $_ } @results;

リストから不要な要素を削る時はgrepを使う。
リストから特定の値を検索するときはgrepかList::Utilのfirstを使う。

リストをその場で変換する時はforを使う。

@temperature = map { F_to_K($_) } @temperature; # 重い

for my $measurement (@temperature) {
    $measurement = F_to_K($measurement); # ok
}

複雑なリスト変換はサブルーチン呼び出しにする。

リスト関数で$_を変更しない。

if-elsif-elsif-elseを連鎖させない。

matchのif連鎖はやめてテーブル参照にする。

ifの連鎖のかわりに?:の3項演算子の連鎖を使う。

do-whileは使わない。

ループ内では除外条件を先に判定する。すべての項目を計算したあとで、まとめて判定するのではなく、計算項目ごとに判定する。

構造化しすぎで無理にループ終了を一元化しない。

whileではなくforやredoを使う。

ループにラベルをつけて、next, last, redoで使う。

ユーザーむけドキュメント、テクニカルドキュメントを区別して書く。

PODのテンプレートを使う。

PODはソースと同じファイルに入れる。

ドキュメントは一カ所にまとめる。

PODはファイルの最後におく。

開発者向けドキュメントは適当に分割する。

プロックコメントテンプレートを使う。

アルゴリズムの説明に1行コメントを入れる。

難しい部分は行末コメントを入れる。

迷ったり悩んだところはコメントを入れる。

コメントを付ける必要があると思ったらコードを分かりやすく書き換えることを検討する。
分かりにくいところは事実を端的に述べるコメントを入れる。

長いテクニカルドキュメントを書く時は=for =cutのPODを使う。
複数の段落やサンプルコードの埋め込みをしたい時は=begin =end =cutを使う。

PODはperldocなどで良く読み返して誤字脱字や分かりにくい文章を修正する。

組み込み関数を使いましょう。自分で作成したコードよりも高速できちんとデバックされている可能性が高い。

ソート中にキーを再計算しない。（SHA-512等）
Perl5.8以降のsortのアルゴリズムはマージソート。計算オーダーはO(N log N)。
Orcishマニューバー。計算した結果がハッシュに有ればそれを使い、無ければ||=のor代入で計算してハッシュに入れる。

my %sha512_of;

@sorted_scripts
    = sort { ($sha512_of{$a} ||= sha512($a))
                cmp
             ($sha512_of{$b} ||= sha512($b))
      }
      @scripts;

Schwartzian変換。（シュワルツ変換）

@sorted_scripts
    = map  { $_->[0] }
      sort { $a->[1] cmp $b->[1] }
      map  { [$_, sha512($_)] }
          @scripts;

cmpと<=>の違い。Plagger/lib/Plagger/Feed.pm sort_entriesの例。一部整形。（$self->entries->dateの数値でソートして、entriesを入れ替えている。降順）

    my @entries = map { $_->[1] }
        sort { $b->[0] <=> $a->[0] }
        map { [ $_->date, $_ ] } $self->entries;

    $self->{entries} = \@entries;

use Memoizeを使ってサブルーチンの返り値を覚えておく

use Digest::SHA qw( sha512 );
use Memoize;
memoize('sha512');

@sorted_scripts = sort { sha512($a) cmp sha512($b) } @scripts;

どれも一長一短なので、実際のリストでベンチマークを取って決める。

reverseを使ってリストを反転する。降順sortが欲しい時は昇順sortをreverseする。
reverse sortは最適化されている。

reverseを使ってスカラーを反転する。スカラーコンテキストを明確にするためscalar指定子を付ける。

add_email_addr(scalar reverse $email_address);

固定幅のデータを抜き出すにはunpackを使う。substrや正規表現はunpackより重い。
'A6 A10 A8'で6文字、10文字、8文字を取得する。
'@0 A6 @8 A10 @20 A8'で列0から6文字、列8から10文字、列20から8文字。
@の値は昇順じゃなくてもいい。

可変幅のデータを抜き出すにはsplitを使う。
第1引数はセパレータ指定。第2引数は文字列。第3引数はフィールドの最大値。
第3引数は必要なフィールド数+1。できるだけ明示的に指定した方が良い。

可変幅の複雑なデータはText::CSV_XSを使う。
use Text::CSV::Simple;

文字列形式のevalは使わない。
eval qq{ sub $subname {...} };で変数名サブルーチンを作るぐらいなら、匿名サブルーチンとSub::Installerを使う。

Sort::Makerでソートルーチン構築を検討する。

lvalueのsubstrではなく引数4つのsubstrを使う。

substr($addr, $country_pos, $COUNTRY_LEN)
    = $country_name($country_code); # 重い!

ではなく

substr $addr, $country_pos, $COUNTRY_LEN, $country_name($country_code); # ok

にする。代入よりも引数4つのsubstrのほうが高速。

lvalue方式のvaluesを利用する。
forループでvaluesを使うとエイリアスのリストが返るので、ループ中で代入できる（lvalueにできる）

<...>ではなくglobを使う。
入力演算だけで<>を使う。

my @files = glob($FILE_PATTERN);

sleepは整数しか有効ではない。秒単位。Time::HiResを使う。
select undef, undef, undef, 0.5;のhackは使わない。

mapとgrepの第1引数に式を使わない。いつもブロックをつかう。

標準ライブラリの関数を使う。
Scalar::Util, List::Util, List::MoreUtilsの関数を使う。
Scalar::Util

• blessed $scalar
• refaddr $scalar
• reftype $scalar
• readonly $scalar
• tainted $scalar
• openhandle $scalar
• weaken $scalar
• is_weak $scalar
• looks_like_number $scalar

List::Util

• first {<条件>} @list
• max @list
• maxstr @list
• min @list
• minstr @list
• shuffle @list
• sum @list
• reduce {<$a $bの2項演算>} @list

List::MoreUtils

• all {<条件>} @list （any(), notall(), none()もある）
• first_index {<条件>} @list　（last_index()もある）
• apply {<変換>} @list　（リストのコピーに変換をかけて新しいリストを返す）
• pairwise {<$a $bの2項演算>} @array1, @array2
• zip @array1, @array2, ...
• uniq @list

サブルーチン呼び出しではカッコを使う。先頭に&を付けない。
（サブルーチンの参照は\&subnameを使う）

組込関数と同じ名前のサブルーチンはダメ。

必ず最初に@_を展開する。サブルーチンは引数を@_配列で受け取る。
$_[0], $_[1]は使わない。

sub hoge {
    my ($self, $context, $args) = @_;
    #略
}

例外は、@_を1回だけすぐに処理するラッパーサブルーチン。

sub say {
    return print @_, "\n";
}
#
say( 'Hello' );

サブルーチン引数が3つ以上のときは名前付き引数のハッシュを使う。

引数があるかどうかチェックするときは、definedか!undef
引数をif !$argsで検証しない。

@_を展開したらデフォルト値を解決する。デフォルト値を他の文で追加しない。

my $cols = exists $args_ref->{cols} ? $args_ref->{cols} : $DEFAULT_WITDH;

スカラーを戻す時はreturn scalarを使う。

リストを返すサブルーチンがスカラーコンテキストで呼ばれた時は明白な値を返す。
（配列の数なのか文字列なのかは、Perl組み込み関数でも実はバラバラだったりする。できるだけ分かりやすく想像しやすいスカラーを返す）

スカラーコンテキストで明白な値をしぼれない時はContextual::Returnを検討する。

サブルーチンプロトタイプは使わない。

省略しないで明示的なreturnを使う。

失敗状態を返すには裸のreturnを使う。return undefは使わない。
（例外を使う）

裸のワードをファイルハンドルに使わない。

レキシカル変数をファイルハンドルにする。

open my $filehandle, '<', $filename

パッケージスコープのファイルハンドルを使う場合はlocalする。
（基本的にパッケージスコープは使わない）

IO::Fileを使うか引数3つのopenを使う。

use IO::File;
my $active = IO::File->new($ACTIVE_LOG, '<')
    or croak "Can't open '$ACTILE_LOG': $OS_ERROR";

open my $stdin, '<', '-' or croak "Can't open stdin: $OS_ERROR";

ファイルへのopen, close, printをするときは結果をチェックする。

ファイルハンドルは出来るだけ速く明示的に閉じる。

open my $fh, '<', $config_file
    or croak "Can't open '$config_file': $OS_ERROR";

my @lines = <$fh>; # 読み込んだらすぐ閉じる
close $fh
    or croak "Can't close '$config_file' after reading: $OS_ERROR";

for (<>)ではなくwhile (<>)を使う。
forはファイルを最後まで読み込んでからループする。whileは1行づつループする。
ただしfor my $n (2..1_000_000_000) {}のような大きな範囲のforループは、実行時評価に最適化されて、999999999個の整数のリストを生成しないので問題は出ない。

ファイル全体を<>で読み込まず、1行ごとのI/Oを使う。
全体を読み込むのはスナップショットが必要な場合や、ファイルが不安定な時や、テキスト処理が複数行に渡る場合だけにする。

ファイルハンドルをdo{ }ブロックで囲む。
ファイル全体をどうしても一度に読み込む場合はFile::Slurp, sysread, do{ local $/; <$fh> };を使う。

my $code = do { local $/; <$in> };

sysread $fh, $text, -s $fh;

Perl6::Slurpを使ってストリームを一気に読む。

use Perl6::Slurp;
my $text = slurp $file_handle;

my @lines = slurp $file_name;

my @lines = slurp $file_name, {chomp => 1};

*STDINは使用しない。*ARGVを使う。（<>はデフォルトで<ARGV>になる）

printではファイルハンドルを中カッコ{ }で囲む。

print {$file} $name, $rank, $serial_num, "\n";

print {*STDERR} $name, $rank, $serial_num, "\n";

use IO::Handle
$file->print( $name, $rank, $serial_num, "\n" );
*STDERR->print( $name, $rank, $serial_num, "\n" );

対話形式で入力するときはプロンプトを表示する。

プロンプト周りはややこしいので自分で書かない。IO::Interactiveを使う。

プロンプト表示はIO::Promptを使う。

待つ処理が続く時は進行状況を伝える。

print {*STDERR} 'Connecting to server...';

Smart::Commentsモジュールで###に続けて書いたコメントが自動的に表示されるのを使う。

selectを使った自動フラッシュは使わない。
自動フラッシュはIO::Handleのautoflush()を使う。

use IO::Handle;
*STDOUT->autoflush();

可能な限り矢印->で逆参照する。

${$list_ref}[0] # NG

ではなく

$list_ref->[0] # Ok

にする。
スライスの時は->は使えない。

@{$list_ref}[0, -1]; # ok

矢印を使うと[ ... ]がスカラーコンテキストになり最後のインデックスだけになる。

$list_ref->[0, -1]; # same ($list_ref->[-1], undef);

基本的に参照は中カッコ{ }で囲む。

シンボリック参照は決して使わない。
（myによるレキシカル変数を使ってパッケージ変数は基本的に使わないので、シンボリック参照も使う必要がない）

weakenを使って循環データ構造からくるメモリリークを回避する。

use Scalar::Util qw( weaken );

正規表現はPerlとは別のもう一つの言語だと思え。

いつも/xフラグを使う。
/xフラグが有効だと、正規表現でスペースや改行やインデントによる整形が使えるようになる。#コメントも使える。

いつも/mフラグを使う。

文字列の境界アンカーとして\Aと\zを使う。
「文字列の先頭」には\Aを使う。/mフラグで^を使わない。「文字列の末尾」には\zを使う。/mフラグで$を使わない。

「文字列の末尾」には\Zでは無く\zを使う。
\Zのかわりに\n?\z。

いつも/sフラグを使う。
/sフラグを使えばドット(.)は改行を含むすべての文字とマッチする。
「改行以外の文字とマッチ」は[^\n]を使う。

Regexp::Autoflagsの義務化を検討する

正規表現が複数行になるときは/.../ではなくm{...}を使う。

/.../かm{...}以外のデリミタをいっさい使わない。

エスケープされたメタ文字ではなく単数文字クラスを使う。

m/ \{ . \. \d{2} \} /xms; # NG

m/ [{] . [.] \d{2} [}] /xms; # Ok

エスケープされたメタ文字ではなく名前付き文字を使う。
use charnames qw( :full );

[a-zA-Z]などではなく\p{Alphabetic}などのプロパティを使う。
perldoc perlunicode

特定の空白ではなく任意の空白をマッチさせる。
空白が要求される場所では\s+
空白を使用出来る場所では\s*

出来るだけ多くマッチするときは具体的に書く。
(.*)&よりも(.*?)&
(.*)&よりも([^&]*)

カッコ( )はキャプチャーのためだけに使う。
選択のためのカッコは(?: )を使ってキャプチャーしない。

キャプチャーが成功して$1や$2に値が入ったかどうかはdefined $1を判定しない。
$1などには他の場所でキャプチャーされた値が入っているかもしれない。

$full_name =~ m/\A (Mrs?|Ms|Dr) \s+ (\S+) \s+ (\S+) \z/xms;
if (defined $1) { # NG!
    ($title, $first_name, $last_name) = ($1, $2, $3);
}

こうじゃなくて

if ($full_name =~ m/\A (Mrs?|Ms|Dr) \s+ (\S+) \s+ (\S+) \z/xms) {
    ($title, $first_name, $last_name) = ($1, $2, $3); # Ok
}

こうする

キャプチャーしたらすぐに適切な名前の変数に代入する。

my ($opt_name, $operator, $opt_val, $comment)
    = $config =~ m/ \A (\S+) \s* (=|[+]=) \s* ([^;]+) ; \s* \# (.*)/xms;

/gcフラグでトークンに分解する。
\Gで「前回のパターンマッチの終わり」

配列から正規表現をjoin '|', map {quotemeta $_} reverse sort @_;で生成する

複雑な正規表現は単純な要素に分解して定数に入れる

Regexp::Commonを使う

一文字の選択(a|b|c)のかわりに文字クラス([abc])を使う

前後の共通部分をまとめる

バックトラックしない場所は(?>...)をつかう。

my $str = '(foo,bar,baz,hoge,fuga)';

$str =~ m{ [(] $ITEM (?> (?:,$ITEM)* ) [)] }xms;

1つの正規表現マッチよりも個別にeqでマッチさせるほうが高速。
大文字と小文字を区別しないためだけに/iフラグ正規表現を使うよりも、lc()を使う方が高速。

失敗の時は、特別な値をreturnしたりフラグを使ったりしないで例外を出す

組み込み関数の失敗でも例外を出す。
Fatalモジュールを使う。

use Fatal qw( open close );

全てのコンテキストでエラーの例外だす。
Fatalで:voidマーカーは使わない。

system関数は成功するとfalse、失敗するとtrueを返すので注意する。
systemを出来るだけ使わずにモジュールを使う。
Perl6::Builtines qw( system )を使う。

回復可能のエラーを含む全てのエラーで例外を出す。

いつもcroak()を使う。

エラー文は受け手が理解出来るように書く。

データをハンドラに伝える時は例外オブジェクトを使う。

エラー文が変化する可能性がある時は例外オブジェクトを使う。

例外処理が複数の場所にある場合は例外オブジェクトを使う。

例外オブジェクトは派生先から評価する。

例外オブジェクトを自動的に作る。CPANのException::Classを使う。

例外変数はレキシカル変数にコピーする。

my $exception = $EVAL_ERROR

Exception::Classのcaught()は$EVAL_ERRORを返すのでそれを代入してもよい。

一貫性のあるコマンドラインオプションと引数を使う。

標準の規則に従う。

--helpなどを標準化する。

入力と出力に同じファイル名を指定出来るようにする。
「unlink 出力ファイル名」の後に出力ファイルをopenする。
IO::InSituモジュールを使う。

Getopt::Longを使う。
CPANのGetopt::Cladeを使う。

インターフェース、ランタイムメッセージ、ドキュメントの一貫性を保つ。
Getopt::Euclidの=for Euclidを使う。

コマンドライン処理の共通機能はモジュールにする。

オブジェクト指向はデフォルトではなく選択肢にする。

擬似ハッシュは使用しない。

制限付きハッシュは使用しない。

ハッシュベースのオブジェクトではなく匿名スカラーでインサイドアウトオブジェクトを使う。
（Class::Accessor::Fastを使ってアクセサを作るのも有りか）

すべてのクラスのコンストラクタの名前はnew()にする。

コンストラクタでオブジェクトを複製しない。
複製が必要ならclone()メソッドを実装する。

いつもデストラクタを定義する。
sub DESTROYでdeleteする。

メソッドはサブルーチンと同じガイドラインに従う。
メソッドの方がパラメータが少ない傾向が有る。
サブルーチンと違い、メソッドには組み込み関数と同じ名前を付けても良い。（組み込み関数と同じような機能のときに違う名前を付けると、類推が難しくなる）

読み取りと書き込みのアクセサを別々に用意する。
get_とset_を使う。
（Class::Accessor::Fastを使うのがいいんじゃないか？）

lvalueアクセサは使用しない。

間接的なオブジェクト構文は使わない。
new ObjectではなくObject->new()を使う。

最小限でなく最適なインターフェースを提供する。

演算子のオーバーロードは代数表記と同じ形のものだけにする。

オブジェクトをブール、数値、文字列に型変換するオーバーロードを検討する。

use baseを使う

インサイドアウトオブジェクトを使う。

引数1つのblessを使用しない。

コンストラクタの引数にはハッシュ参照を使う。ラベル付きの値を渡す。

sub new {
    my ($class, $arg_ref) = @_;

    my $new_object = bless anon_scalar(), $class;

    $client_num_of(ident $new_object) = $arg_ref->{client_num};
    $name_of(ident $new_object)       = $arg_ref->{client_name};

    return $new_object;
}

ハッシュのハッシュを渡して、ベースクラスの引数をクラス名で指定する。
Class::Std::Utils

生成、初期化、破棄のプロセスを分離する。

Class::Stdを使う。

デストラクタでClass::Stdで:ATTRを使う。

初期化にClass::Stdの:ATTR( init_args => 'hoge' );を使う。

強制的な型変換はClass::Stdの:STRINGIFY、:NUMERIFY、:BOOLIFYメソッドとして指定する。

SUPER::呼び出しのかわりにClass::Stdの:CUMULATIVEメソッドを使う。

AUTOLOAD()を使わない。
Class::StdのAUTOMETHOD()を検討する。

モジュールのインターフェースを最初に設計する。

重複するコードはサブルーチンにする。重複するサブルーチンはモジュールにする。

v1.0.3のvstringを使ってはダメ。
versionモジュールとqv(...)コンストラクタを使う。

use version; our $VERSION = qv('1.0.3');

「このバージョン以上じゃないと動作しない」という指定を書く。
use 5.006001;やuse only q( 5.6.1- !5.8.0 );を使う。

エクスポートは慎重に。必要な場合にだけ使う。
@EXPORTと@EXPORT_OKで分ける。

宣言的なエクスポートを検討する。Perl6::Export::Attrsモジュールを使う。

モジュールのインターフェースの一部としてパッケージ変数を使わない。

新しいモジュールを作る時はCPANのModule::Starterで自動生成を使う。
Module::Starter::PBPも使う。

自分でコードを1から書かずに、可能な限り標準ライブラリを使う。
perldoc perlmodlib

CPANモジュールを使用する。

最初にテストケースを作る。
コード本体を書く前にテストコードを書く。

Test::Simple、Test::Moreを使ってテストを標準化する。
（今どきだったらTest::Baseか？）

Test::Harnessを使ってテストスイートを標準化する。
proveコマンドが使える。

失敗するテストスイートを作る。

起こりそうな事と、起こらなそうな事を両方テストする。
不正な動作を検出するのにふさわしい場所。

• 有効範囲の最大値と最小値
• 最小値よりも少し小さい値と、最大値よりも少し大きい値
• 負数値、正数値、0
• 非常に小さい負数値、正数値
• 空の文字列と複数行の文字列
• "\0"などの制御文字が含まれた文字列
• ASCII以外の文字列（Latin-1、Unicode）
• undefとundefのリスト
• '0', '0E0', '0.0', '0 but true'
• 空のリスト、空の配列、空のハッシュ
• 重複する値が含まれたリスト
• 決して入力される事の無い入力値
• 必ず利用出来るはずのリソースとのやりとり
• 数値が期待される場所への数値でない入力、数値が期待されない場所への数値の入力
• 参照が期待される場所への非参照値。参照が期待されない場所への参照値
• サブルーチン、メソッドへの引数の不足
• サブルーチン、メソッドへの余分な引数
• 順序がバラバラと位置指定の引数
• 不正なラベルが付いたキーと値の引数
• モジュールの不適切なバージョンのロード
• これまで遭遇したことのあるすべてのバグ

デバッグの前に新しいテストケースを追加する。

いつもuse strictを使う。

いつも警告を明示的に表示する。
use warningsを使う。

use strictとuse warningsを使っていて警告が出なくても、正確であると決めつけない。

no strict 'refs'などを使う時は最も狭いスコープで使う。

perlデバッガを習得する。

手動でのデバッグはシリアライズされた出力をwarnする。

use Data::Dumper qw( Dumper );
warn Dumper ($results);

warnではなくSmart::Commentsの###も検討する。

日本では、やっぱり大企業でブログを書くのは難しいのか？ : tokuriki.com_

ログインしなくても見える画像 | Okumura's Blog_

コメント欄_ の反応も仕方が無いか。
根本的にJ-CAST記者は「空気が読めない困ったタイプの人たち」というところに着目して記事を書いているが。元々のネタ展開として「モヒカン族が良いよ」とも「ムラ社会文化が良いよ」とも書かないように注意して書いたんだよなぁ。（J-CASTニュースは当然だけどJ-CAST記者の領域なので、何をどう解釈して記事を書いてもJ-CASTの自由だから良いんだけど）
まぁ2005年8月のネタを、つい数日前に「初めて知ったのですがどういう言葉なのか教えてください」と取材されて。モヒカン族はてなグループとかキーワードはほとんど読んでいないという感じだったので、ざっと説明したり。
ネーミングの経緯とか、当時ウォッチしていた新聞記者炎上のエピソードとかを話して。ネットは殺伐としたやり取りが多く、まるで大関東地獄地震の後かサザンクロスシティのようだと思ったよ。みたいな事を返答したりした。
あと今更だけど。
あれは技術者に対するステロタイプなイメージとして良くありがちな「ガリガリに痩せていて色白な理系メガネ君」というのを、あえて極端に逆サイドに振って、北斗の拳の筋骨隆々なモヒカン刈りの悪役雑魚になぞらえたギャップネタだったりするんだよな。（「汚物は消毒だぁ」で村人炎上をblog炎上に繋げるための前振りだとか、「サルまん」の弁髪編集者のギャップネタなどもイメージのネタ元だったりする）。だから「殺伐と淡々とした口調＝荒くれ者で空気が読めない無礼者」という直結は解釈としては浅かったりする。あれは「おいおい、筋骨隆々のモヒカン刈りの男がキーボード叩いてネットバトルしているのかよ」というツッコミが欲しかったりもした（これはオレのネタ振りが甘かっただけなので仕方が無いが）。

M記者が、おれのWeb日記の新聞記者炎上ウォッチ記事を読んでそう解釈したんだろうけど。
まぁ基本的にはあれを「モヒカン族対処法」として受け取ってもらっても、それはそれで良いんだけど。
モヒカン族の話題で一番言いたかった事はちょっと違って。
「空気が読めない無礼な奴だから、論理的に正しくても排除していいのだ」というムラ社会文化や、「論理的に間違っているから、どんなに感情面でマズくても正確に指摘すれば良いのだ」というモヒカン族文化は、鏡のようなもんじゃないかなぁ。どっちが良くてどっちが悪いというもんじゃないよな。んで「糸井重里メソッド」という、感情面に最大限に最適化された主張テクニックというのも有ったりするよね。優越感や自尊心や上下関係を気にしすぎたり、逆に気にしなさすぎたりして、ピュアに悩んでたりするのなら、まず面白おかしく分類して客観視するのも良いんじゃないかな。
……というような意図によるネタ話だったんだけど。
なぜか学者肌の人からは「モヒカン族というレッテルを貼って馬鹿にしているのか」と言われたり、群れを気にしすぎる人からは「ムラ社会文化の他人の目を気にすることをけなしている。殺伐と淡々としていればいいのだと煽動している」と言われたり。（多分、どっちの人も自分の性格の気にしている部分に引っかかったんだと思う）

ウェブデザイナーだと思っている人はちゃんと読んでいないからどうでもいいとして。「otsune(本人) ◆Az5.wRptWI」って別人ですよ！
オレが2chに本人書き込みするときはBe付きで書き込みしてるって。